An old rotary phone can be used for a number of purposes in your Arduino projects – use it as a novel input device, or use the Arduino to interface a rotary phone to your computer.
This is a very basic guide describing how to interface the dial to an Arduino, and get the number dialed passed into a computer over the Arduino’s serial link.
Step 1 Remove the dial from the phone
First step is to remove the dial unit from the phone. I’m using a GPO phone of some sort from the 1970s.
On this phone, the dial popped straight out – I just needed to give it a tug. If it doesn’t, you may have to open up the phone and work out how to get it off.
There were five cables connected to the back of the dial unit. On my phone, these were regular spade connections, so I loosened the screws and pulled them out. If you want to re-assemble your phone, remember to record which color wire goes to which connection.
Step 2 Identify the switch
Once the dial is out, it should be relatively easy to see how the dial converts rotary movement into pulses. Try spinning the dial by hand and watching the movement on the back. You should see a switch making and breaking a circuit rapidly – so if you dial ‘9’, the switch should engage nine times.
For those of you who may never have used a rotary dial before – remember that the dialing only happens when you let go the number and let it spool back .
I’ve documented how it works for my phone in the Notes of the photo below.
There’s also a blurry video of the mechanism working.
Step 3 Make the circuit
Once you have found the switch that is being made and broken, you should be able to identify the connections by following the wires back to the connection terminals. In my case, the two sides of the switch are connected to the two leftmost terminals.
Hook up these terminals to some jumper wires, and get prototyping! The switch in my dial is always-on, and is broken for each pulse when dialling, so I used the very simple circuit below. Pin 2 will go HIGH for each pulse as the dial rotates.
When the phone isn’t being dialed, the switch in the dial unit is closed (a so-called NORMALLY CLOSED switch, for obvious reasons) so the circuit connects pin 2 to ground (which to the Arduino is LOW). This is because there is much less resistance through the 470 ohm resistor than the 10K resistor.
When the phone is being dialed, the switch opens and closes rapidly (for a 9, it will open and close again nine times, remember). When the switch is open, pin 2 is not connected to ground – instead it is connected to the 5V supply through a resistance of 10470 ohms. This is interpreted by the Arduino as a HIGH.
If your dial has a NORMALLY OPEN switch, then swapping the positions of the 10K resistor and the dial should do the trick.
Step 4 Develop the code
Now we need some code for the Arduino to count the pulses and send the total number per number dialed back through the serial port.
My code’s below. As we’re dealing with mechanicals here, yours may differ. Try playing about with the debounce constant and the ‘how long do we wait before assuming dial has finished rotating’ constant.
I’ve tried to comment it as neatly as I can. Hopefully it’s pretty simple.
int needToPrint = 0;
int count;
int in = 2;
int lastState = LOW;
int trueState = LOW;
long lastStateChangeTime = 0;
int cleared = 0;
// constants
int dialHasFinishedRotatingAfterMs = 100;
int debounceDelay = 10;
void setup()
{
Serial.begin(9600);
pinMode(in, INPUT);
}
void loop()
{
int reading = digitalRead(in);
if ((millis() – lastStateChangeTime) > dialHasFinishedRotatingAfterMs) {
// the dial isn’t being dialed, or has just finished being dialed.
if (needToPrint) {
// if it’s only just finished being dialed, we need to send the number down the serial
// line and reset the count. We mod the count by 10 because ‘0’ will send 10 pulses.
Serial.print(count % 10, DEC);
needToPrint = 0;
count = 0;
cleared = 0;
}
}
if (reading != lastState) {
lastStateChangeTime = millis();
}
if ((millis() – lastStateChangeTime) > debounceDelay) {
// debounce – this happens once it’s stablized
if (reading != trueState) {
// this means that the switch has either just gone from closed->open or vice versa.
trueState = reading;
if (trueState == HIGH) {
// increment the count of pulses if it’s gone high.
count++;
needToPrint = 1; // we’ll need to print this number (once the dial has finished rotating)
}
}
}
lastState = reading;
}
For more Detail: Interface a rotary phone dial to an Arduino
